;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; Advanced Communication Board Developers Toolkit
;; (c)Copyright 1993-1995, Sealevel Systems Incorporated
;;
;; ACBTERM.ASM - TERMINAL EMULATION PROGRAM USING THE ACB-II CARD.
;; ASYNCRONOUS FORMAT, 9600 BAUD, NO PARITY, 8 STOP BITS, 1 STOP BIT.
;; POLLED PROGRAM
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

CODE SEGMENT
ASSUME CS:CODE,DS:CODE
	  ORG 100H
START:	  JMP OVER

;8530 INITIALIZATION VALUES - SEE 8530 DATA SHEET FOR DETAILS

INIT DB 9,0C0H		      ;FORCE HARDWARE RESET
     DB 4,44H		      ;X16 MODE, 1 STOP BIT/CHARACTER
     DB 3,0C1H		      ;RX ENABLE, RX 8 BITS/CHARACTER
     DB 2,0		      ;INTERRUPT VECTOR (NOT USED)
     DB 5,68H		      ;TX ENABLE, TX 8 BITS/CHARACTER
     DB 6,0		      ;SYNC INFORMATION (NOT USED)
     DB 7,0		      ;SYNC INFORMATION (NOT USED)
     DB 10,0		      ;NRZ/FM/LOOP MODE (NOT USED)
     DB 11,56H		      ;RX CLOCK/TX CLOCK/TRxC OUT = B.R. GENERATOR
     DB 12,14		      ;TIME CONSTANT - LOW BYTE - 9600 BAUD
     DB 13,0		      ;TIME CONSTANT - HIGH BYTE
     DB 14,3		      ;BAUD RATE GENERATOR ENABLED/SOURCE
     DB 15,0		      ;MISCELLANEOUS CONTROL BITS (NOT USED)
     DB 0,0D0H		      ;RESET TX UNDERRUN - RESET EXT/STATUS INTERRUPTS
     DB 1,00H		      ;NO DMA - NO INTS
INITE LABEL BYTE
MESS DB 'TERMINAL EMULATION                         [Press ESC to exit]$'

OVER:	  MOV AH,6	      ;CLEAR SCREEN
	  MOV CX,0
	  MOV DX,184FH
	  MOV BH,7
	  MOV AL,0
	  INT 10H

	  MOV DX,1800H	      ;SET CURSOR
	  MOV AH,2
	  MOV BH,0
	  INT 10H

	  MOV DX,OFFSET MESS  ;PRINT MESSAGE
	  MOV AH,9
	  INT 21H

;SETS UP 8530 - WRITES REGISTER NUMBER AND IT'S ASSOCIATED VALUE TO DATA PORT
;	       - NOTE: THIS IS A TWO STEP PROCESS

	  MOV DX,239H	      ;CHANNEL (A) CONTROL PORT (BASE ADDRESS+1)
			      ;CHANNEL (B) CONTROL PORT=23B HEX (BASE ADDRESS+3)
	  MOV BX,OFFSET INIT  ;LOCATION OF INITIALIZATION VALUES
	  MOV CX,OFFSET INITE ;END OF DATA TABLE
	  SUB CX,BX	      ;GET PARAMETER COUNT
	  SAR CX,1	      ;DIVIDE BY 2

L1:	  MOV AL,CS:[BX]      ;GET REGISTER
	  OUT DX,AL	      ;SEND TO 8530 CONTROL PORT
	  INC BX	      ;INCREMENT TO PARAMETER
	  MOV AL,CS:[BX]      ;GET PARAMETER
	  OUT DX,AL	      ;SEND TO 8530 CONTROL PORT
	  INC BX	      ;INCREMENT TO REGISTER
	  LOOP L1	      ;LOOP UNTIL DONE

	  MOV DX,0	      ;INITIAL CURSOR POSITION

T3:	  MOV AH,2	      ;SET CURSOR POSITION
	  MOV BH,0
	  INT 10H

TOP:	  MOV AH,1	      ;CHECK KEYBOARD
	  INT 16H	      ;KEY PRESSED?
	  JZ NOKEY	      ;NO - CHECK RECEIVE PORT
	  MOV AH,0	      ;GET KEY
	  INT 16H
	  CMP AL,27	      ;YES - IS IT ESCAPE?
	  JZ XIT	      ;YES - EXIT
	  PUSH AX	      ;NO - SAVE CHARACTER
T4:	  MOV DX,239H	      ;SEND IT - CHANNEL (A) CONTROL PORT
	  MOV AL,0	      ;CHECK READ REGISTER 0 - STATUS INFORMATION
	  OUT DX,AL
	  JMP $+2	      ;DELAY FOR 8530 RECOVERY TIME
	  IN AL,DX	      ;READ STATUS
	  AND AL,4	      ;TX BUFFER EMPTY?
	  JZ T4 	      ;NO - WAIT
	  POP AX	      ;YES - SEND CHARACTER
	  MOV DX,238H	      ;CHANNEL (A) DATA PORT (23A HEX FOR CHANNEL B)
	  OUT DX,AL	      ;SEND IT

NOKEY:	  MOV DX,239H	      ;CHANNEL (A) CONTROL PORT
	  MOV AL,0	      ;CHECK READ REGISTER 0 - STATUS INFORMATION
	  OUT DX,AL
	  JMP $+2	      ;DELAY FOR 8530 RECOVERY TIME
	  IN AL,DX	      ;READ STATUS
	  AND AL,1	      ;DATA READY?
	  JZ TOP	      ;NO - CHECK KEYBOARD
			      ;YES - GET CHARACTER
	  MOV DX,238H	      ;CHANNEL (A) DATA PORT
	  IN AL,DX	      ;READ CHARACTER
	  MOV AH,14	      ;PRINT IT
	  MOV BH,0
	  INT 10H
	  JMP TOP	      ;START OVER

XIT:	  MOV AX,4C00H	      ;TERMINATE PROGRAM
	  INT 21H
CODE ENDS
END START