;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;
;; Advanced Communication Board Developers Toolkit
;; (c)Copyright 1993-1995, Sealevel Systems Incorporated
;;
;; SDLCTERM.ASM - SENDS CHARACTER TYPED AS A 1 BYTE FRAME.
;;      	    - RECEIVES AND DISPLAYS INCOMING FRAMES.
;;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

CODE SEGMENT
ASSUME CS:CODE,DS:CODE
	  ORG 100H
START:	  JMP OVER

;82530 INITIALIZATION VALUES - SEE 82530 DATA SHEET FOR DETAILS

INIT DB 9,0C0H		      ;FORCE HARDWARE RESET
     DB 4,20H		      ;X1 MODE, SDLC MODE
     DB 3,0C1H		      ;RX ENABLE, RX 8 BITS/CHARACTER
     DB 2,0		      ;INTERRUPT VECTOR
     DB 5,69H		      ;TX 8 BITS/CHARACTER, TX ENABLED, CRC ENABLED
     DB 6,0		      ;ADDRESS
     DB 7,7EH		      ;SDLC FLAG
     DB 10,0		      ;NRZ/FM/LOOP MODE (NOT USED)
     DB 11,16H		      ;RX CLOCK = RTXC PIN
     DB 12,14H		      ;TIME CONSTANT - LOW BYTE - 76.8K BAUD
     DB 13,0		      ;TIME CONSTANT - HIGH BYTE
     DB 14,3		      ;BAUD RATE GENERATOR ENABLED/SOURCE
     DB 15,0		      ;MISCELLANEOUS CONTROL BITS (NOT USED)
     DB 0,80H		      ;RESET CRC
     DB 0,30H		      ;ERROR RESET
     DB 0,90H		      ;RESET TX UNDERRUN - RESET EXT/STATUS INTERRUPTS
     DB 0,90H		      ;RESET TX UNDERRUN - RESET EXT/STATUS INTERRUPTS
     DB 1,0H		      ;READY/DMA REQUEST - READY SELECTED
INITE LABEL BYTE

MESS DB 'SDLC terminal - keys pressed will be transmitted as a 1 byte frame.',10,13
     DB 'Incoming frames up to 200 bytes are displayed. Type [ ESC ] to exit.',10,10,13,'$'

RECBUFF DB 200 DUP(0)
COUNT DW 0

;==============================================================================
OVER:	  MOV AH,6	      ;CLEAR SCREEN
	  MOV CX,0
	  MOV DX,184FH
	  MOV BH,7
	  MOV AL,0
	  INT 10H

	  MOV AH,2			;SET CURSOR AT UPPER L.H. CORNER
	  MOV BH,0
	  XOR DX,DX
	  INT 10H
	  MOV DX,OFFSET MESS		;PRINT TITLE
	  MOV AH,9
	  INT 21H

;==============================================================================
;SETS UP 82530 - WRITES REGISTER NUMBER AND IT'S ASSOCIATED VALUE TO DATA PORT
;	       - NOTE: THIS IS A TWO STEP PROCESS

	  MOV DX,239H	      ;CHANNEL (A) CONTROL PORT (BASE ADDRESS+1)
			      ;CHANNEL (B) CONTROL PORT=23B HEX (BASE ADDRESS+3)
	  MOV BX,OFFSET INIT  ;LOCATION OF INITIALIZATION VALUES
	  MOV CX,OFFSET INITE ;END OF DATA TABLE
	  SUB CX,BX	      ;GET PARAMETER COUNT
	  SAR CX,1	      ;DIVIDE BY 2

L1:	  MOV AL,CS:[BX]      ;GET REGISTER
	  OUT DX,AL	      ;SEND TO 82530 CONTROL PORT
	  INC BX	      ;INCREMENT TO PARAMETER
	  MOV AL,CS:[BX]      ;GET PARAMETER
	  OUT DX,AL	      ;SEND TO 82530 CONTROL PORT
	  INC BX	      ;INCREMENT TO REGISTER
	  LOOP L1	      ;LOOP UNTIL DONE

;=============================================================================

	  MOV SI,OFFSET RECBUFF 	;RECEIVE BUFFER POINTER
	  MOV COUNT,0			;CHARACTER COUNT

NO_CHAR:  MOV DX,239H			;CONTROL PORT
	  XOR AL,AL			;RR0
	  OUT DX,AL
	  JMP $+2
	  IN AL,DX
	  TEST AL,1			;DATA READY?
	  JZ CX_KBRD			;NO

GET_CHAR: MOV DX,238H			;YES - DATA PORT
	  IN AL,DX			;READ CHARACTER

	  MOV CS:[SI],AL		;SAVE IT
	  INC SI			;ADJUST CHARACTER COUNT
	  MOV DX,239H			;CONTROL PORT
	  MOV AL,1			;RR1
	  OUT DX,AL
	  JMP $+2
	  IN AL,DX
	  TEST AL,80H			;END OF FRAME?
	  JNZ EOF			;YES
WAIT_RX:  MOV DX,239H			;NO - CONTROL PORT
	  XOR AL,AL			;RR0
	  OUT DX,AL
	  JMP $+2
	  IN AL,DX
	  TEST AL,1			;DATA READY?
	  JZ WAIT_RX			;NO
	  JMP GET_CHAR

EOF:	  MOV CX,SI			;END OF FRAME - GET RECEIVED CHAR COUNT
	  MOV SI,OFFSET RECBUFF 	;CHARACTER BUFFER
	  SUB CX,SI
	  SUB CX,2			;DON'T PRINT 2 BYTES OF CRC
WRT1:	  MOV AL,CS:[SI]		;GET CHARACTER FROM RECEIVE BUFFER
	  INC SI
	  MOV AH,14			;PRINT IT
	  MOV BH,0
	  INT 10H
	  LOOP WRT1			;LOOP UNTIL DONE

	  MOV SI,OFFSET RECBUFF 	;RESET BUFFER POINTER

CX_KBRD:  MOV AH,1			;CHECK KEYBOARD
	  INT 16H			;ANY KEY PRESSED?
	  JZ NO_CHAR			;NO - CHECK DATA PORT

GET_KEY:  MOV AH,0			;GET CHAR
	  INT 16H
	  CMP AL,27			;ESC?
	  JZ XIT			;YES - EXIT

	  PUSH AX
	  CALL WAIT_TX			;WAITS FOR TX EMPTY
	  POP AX
	  MOV DX,238H			;DATA PORT
	  OUT DX,AL			;SEND IT

	  MOV DX,239H			;CONTROL PORT
	  XOR AL,AL			;WR0
	  OUT DX,AL
	  JMP $+2
	  MOV AL,0C0H			;RESET TX UNDERRUN LATCH
	  OUT DX,AL

	  JMP NO_CHAR			;CHECK DATA PORT

XIT:	  MOV AH,6			;CLEAR SCREEN
	  MOV CX,0
	  MOV DX,184FH
	  MOV BH,7
	  MOV AL,0
	  INT 10H

	  MOV AH,2			;SET CURSOR AT UPPER L.H. CORNER
	  MOV BH,0
	  XOR DX,DX
	  INT 10H

	  MOV AX,4C00H			;TERMINATE PROGRAM
	  INT 21H

WAIT_TX PROC NEAR
	  MOV DX,239H
WT1:	  XOR AL,AL			;WR0
	  OUT DX,AL
	  JMP $+2
	  IN AL,DX
	  TEST AL,4			;TX EMPTY?
	  JZ WT1			;NO - WAIT
	  RET
WAIT_TX ENDP

CODE ENDS
END START