;
; (c)Copyright Sealevel Systems Incorporated, 1993 - 1995
;
;INTTEST.ASM - SENDS A MESSAGE TO A SEALEVEL PCIO BOARD RUNNING INTDRIVE.EXE
;	     - SELECT A BOARD BASE ADDRESS OF 378 HEX

DATAPORT EQU 378H			;DATA PORT = BASE ADDRESS
CONTROL EQU 37AH			;CONTROL PORT = BASE+2

CODE SEGMENT
ASSUME CS:CODE,DS:CODE
	  ORG 100H
START:	  JMP OVER

MESS DB 'THE QUICK BROWN FOX JUMPED OVER THE LAZY DOG'	    ;TEST MESSAGE

OVER:	  MOV DX,CONTROL		;CONTROL PORT
	  MOV AL,0			;SET INTERRUPT PULSE LOW
	  OUT DX,AL

	  MOV CX,44			;CHARACTER COUNT
	  MOV BX,OFFSET MESS		;MESSAGE INDEX

L1:	  MOV AL,[BX]			;GET THE CHARACTER
	  INC BX			;ADJUST THE INDEX
	  MOV DX,DATAPORT		;DATA PORT
	  OUT DX,AL			;SEND THE CHARACTER
	  JMP $+2			;DELAY

	  MOV DX,CONTROL		;CONTROL PORT
	  MOV AL,4			;SET INTERRUPT PULSE HIGH - GENERATES
	  OUT DX,AL			;AN INTERRUPT ON THE RECEIVING BOARD

	  PUSH CX			;SMALL DELAY
	  MOV CX,0FFH
L2:	  LOOP L2
	  POP CX

	  MOV AL,0			;SET INTERRUPT PULSE LOW
	  OUT DX,AL
	  JMP $+2

	  LOOP L1			;LOOP UNTIL THE TRANSFER IS COMPLETE

	  MOV AX,4C00H			;EXIT TO DOS
	  INT 21H
CODE ENDS
END START