Example 1.2. Program to Unpack an OpenOffice.org Document

#!/usr/bin/perl

#
#	Unpack an OpenDocument file to a directory.

#
#	Archive::Zip is used to unzip files.
#	File::Path is used to create and remove directories.
#
use Archive::Zip;
use File::Path;
use strict;

my $file_name;
my $dir_name;
my $suffix;
my $zip;
my $member_name;
my @member_list;

if (scalar @ARGV != 1)
{
	print "Usage: $0 filename\n";
	exit;
}

$file_name = $ARGV[0];

#
#	Only allow filenames that have valid OpenDocument extensions
#
if ($file_name =~ m/\.(o[dt][tgpscif]|odm|oth)/)
{
	$suffix = $1;
	
	#
	#	Create directory name based on filename
	#
	($dir_name = $file_name) =~ s/\.$suffix//;
	$dir_name .= "_$suffix";
	
	#
	#	Forcibly remove old directory, re-create it,
	#	and unzip the OpenOffice.org file into that directory
	#
	rmtree($dir_name, 0, 0);
	mkpath($dir_name, 0, 0755);
	
	$zip = Archive::Zip->new( $file_name );
	@member_list = $zip->memberNames( );
	
	foreach $member_name (@member_list)
	{
		$zip->extractMember( $member_name, "$dir_name/$member_name" );
	}
	
	print "$file_name unpacked.\n";
}
else
{
	print "This does not appear to be an OpenDocument file.\n";
	print "Legal suffixes are .odt, .ott, .odg, .otg, .odp, .otp,\n";
	print ".ods, .ots, .odc, .otc, .odi, .oti, .odf, .otf, .odm, and .oth\n";
}

Example 1.3. Program to Pack Files to Create an OpenDocument File

#!/usr/bin/perl

#
#	Repack a directory to an OpenDocument file
#
#	Directory xyz_odt will be packed into xyz.odt, etc.
#
#

use Archive::Zip;	# to zip files
use Cwd;			# to get current working directory

use strict;

my $dir_name;		# directory name to zip
my $file_name = "";	# destination file name
my $suffix;			# file extension
my $current_dir;	# current directory
my $zip;			# a zip file object

if (scalar @ARGV < 1 || scalar @ARGV > 2)
{
	print "Usage: $0 directoryname [newfilename]\n";
	exit;
}

$dir_name = $ARGV[0];

#
#	If no new filename is given, create a filename
#	based on directory name
#

if ($ARGV[1])
{
	$file_name = $ARGV[1];
}
else
{
	if ($dir_name =~ m/_(o[dt][tgpscif]|odm|oth)/)
	{
		$suffix = $1;
		($file_name = $dir_name) =~ s/(_$suffix)//;
		$file_name .= ".$suffix";
	}
	else
	{
		print "This does not appear to be an unpacked OpenDocument file.\n";
		print "Legal suffixes are _odt, _ott, _odg, _otg, _odp, _otp, _ods,\n";
		print "_ots, _odc, _otc, _odi, _oti, _odf, _otf, _odm, and _oth\n";
		$file_name = "";
	}
}

if ($file_name ne "")
{
	$zip = Archive::Zip->new();
	
	$current_dir = cwd();

	if (chdir($dir_name))
	{
		$zip->addTree( '.' );
		$zip->writeToFileNamed( "../$file_name" );
		print "$dir_name packed to $file_name.\n";
		chdir($current_dir);
	}
	else
	{
		print "Could not change directory to $dir_name\n";
	}
}